it-swarm-pt.tech

Atualizando todas as tabelas dinâmicas da minha pasta de trabalho do Excel com uma macro

Eu tenho uma pasta de trabalho com 20 tabelas dinâmicas diferentes. Existe alguma maneira fácil de encontrar todas as tabelas dinâmicas e atualizá-las no VBA?

78
Lipis

Sim.

ThisWorkbook.RefreshAll

Ou, se sua versão do Excel tiver idade suficiente,

Dim Sheet as WorkSheet, Pivot as PivotTable
For Each Sheet in ThisWorkbook.WorkSheets
    For Each Pivot in Sheet.PivotTables
        Pivot.RefreshTable
        Pivot.Update
    Next
Next
158
GSerg

Esse código do VBA atualizará todas as tabelas/gráficos dinâmicos na pasta de trabalho.

Sub RefreshAllPivotTables()

Dim PT As PivotTable
Dim WS As Worksheet

    For Each WS In ThisWorkbook.Worksheets

        For Each PT In WS.PivotTables
          PT.RefreshTable
        Next PT

    Next WS

End Sub

Outra opção não programática é:

  • Clique com o botão direito em cada tabela dinâmica
  • Selecione as opções da tabela
  • Marque a opção 'Atualizar em aberto'.
  • Clique no botão OK

Isso atualizará a tabela dinâmica sempre que a pasta de trabalho for aberta.

25
Robert Mearns

ActiveWorkbook.RefreshAll atualiza tudo, não apenas as tabelas dinâmicas, mas também as consultas ODBC. Eu tenho um par de consultas VBA que se referem a conexões de dados e usando esta opção falha como o comando executa as conexões de dados sem o detalhe fornecido a partir do VBA

Eu recomendo a opção se você quiser apenas que os pivôs sejam atualizados

Sub RefreshPivotTables()     
  Dim pivotTable As PivotTable     
  For Each pivotTable In ActiveSheet.PivotTables         
    pivotTable.RefreshTable     
  Next 
End Sub 
19
Kevin

Em determinadas circunstâncias, você pode querer diferenciar entre uma tabela dinâmica e seu PivotCache. O Cache tem seu próprio método de atualização e suas próprias coleções. Portanto, poderíamos ter atualizado todos os PivotCaches em vez das Tabelas Dinâmicas.

A diferença? Quando você cria uma nova Tabela Dinâmica, pergunta se deseja usá-la com base em uma tabela anterior. Se você disser não, essa Tabela Dinâmica receberá seu próprio cache e dobrará o tamanho dos dados de origem. Se você disser sim, manterá seu WorkBook pequeno, mas adicionará a uma coleção de Tabelas Dinâmicas que compartilham um único cache. Toda a coleção é atualizada quando você atualiza qualquer tabela dinâmica dessa coleção. Você pode imaginar, portanto, qual seria a diferença entre atualizar cada cache no WorkBook, em comparação com a atualização de cada Tabela Dinâmica no WorkBook.

8
Steve WahWah Weeks

Há uma opção refresh all na barra de ferramentas Tabela Dinâmica. É suficiente. Não precisa fazer mais nada.

Pressione ctrl + alt + F5

5
Prasenjit

Você tem uma coleção PivotTables em um objeto VB Worksheet. Então, um loop rápido como esse funcionará:

Sub RefreshPivotTables()
    Dim pivotTable As PivotTable
    For Each pivotTable In ActiveSheet.PivotTables
        pivotTable.RefreshTable
    Next
End Sub

Notas das trincheiras:

  1. Lembre-se de desproteger quaisquer folhas protegidas antes de atualizar a Tabela Dinâmica.
  2. Salve frequentemente.
  3. Vou pensar mais e atualizar no devido tempo ... :)

Boa sorte!

1
LohanJ

Mesmo podemos atualizar conexão particular e por sua vez, ele atualizará todos os pivots ligados a ele.

Para este código eu criei slicer da tabela presente no Excel:

Sub UpdateConnection()
        Dim ServerName As String
        Dim ServerNameRaw As String
        Dim CubeName As String
        Dim CubeNameRaw As String
        Dim ConnectionString As String

        ServerNameRaw = ActiveWorkbook.SlicerCaches("Slicer_ServerName").VisibleSlicerItemsList(1)
        ServerName = Replace(Split(ServerNameRaw, "[")(3), "]", "")

        CubeNameRaw = ActiveWorkbook.SlicerCaches("Slicer_CubeName").VisibleSlicerItemsList(1)
        CubeName = Replace(Split(CubeNameRaw, "[")(3), "]", "")

        If CubeName = "All" Or ServerName = "All" Then
            MsgBox "Please Select One Cube and Server Name", vbOKOnly, "Slicer Info"
        Else
            ConnectionString = GetConnectionString(ServerName, CubeName)
            UpdateAllQueryTableConnections ConnectionString, CubeName
        End If
    End Sub

    Function GetConnectionString(ServerName As String, CubeName As String)
        Dim result As String
        result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
        '"OLEDB;Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False"
        GetConnectionString = result
    End Function

    Function GetConnectionString(ServerName As String, CubeName As String)
    Dim result As String
    result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
    GetConnectionString = result
End Function

Sub UpdateAllQueryTableConnections(ConnectionString As String, CubeName As String)
    Dim cn As WorkbookConnection
    Dim oledbCn As OLEDBConnection
    Dim Count As Integer, i As Integer
    Dim DBName As String
    DBName = "Initial Catalog=" + CubeName

    Count = 0
    For Each cn In ThisWorkbook.Connections
        If cn.Name = "ThisWorkbookDataModel" Then
            Exit For
        End If

        oTmp = Split(cn.OLEDBConnection.Connection, ";")
        For i = 0 To UBound(oTmp) - 1
            If InStr(1, oTmp(i), DBName, vbTextCompare) = 1 Then
                Set oledbCn = cn.OLEDBConnection
                oledbCn.SavePassword = True
                oledbCn.Connection = ConnectionString
                oledbCn.Refresh
                Count = Count + 1
            End If
        Next
    Next

    If Count = 0 Then
         MsgBox "Nothing to update", vbOKOnly, "Update Connection"
    ElseIf Count > 0 Then
        MsgBox "Update & Refresh Connection Successfully", vbOKOnly, "Update Connection"
    End If
End Sub
0
Rajiv Singh

O código

Private Sub Worksheet_Activate()
    Dim PvtTbl As PivotTable
        Cells.EntireColumn.AutoFit
        For Each PvtTbl In Worksheets("Sales Details").PivotTables
        PvtTbl.RefreshTable
        Next
End Sub 

funciona bem.

O código é usado no módulo de ativação de folhas, portanto, exibe um piscar de olhos quando a folha é ativada.

0
user3564681