it-swarm-pt.tech

Dividir entradas separadas por vírgula em novas linhas

Atualmente, tenho esses dados em uma planilha

Col A   Col B
1       angry birds, gaming
2       nirvana,rock,band

O que eu quero fazer é dividir as entradas separadas por vírgula na segunda coluna e inserir em novas linhas, como abaixo:

Col A   Col B
1   angry birds
1   gaming
2   nirvana
2   rock
2   band

Estou certo de que isso pode ser feito com o VBA, mas não consegui descobrir isso sozinho.

16
redGREENblue

É melhor usar matrizes variantes em vez de loops de células - eles são muito mais rápidos em termos de código quando os conjuntos de dados são significativos. Mesmo que o código seja mais longo :)

Este exemplo abaixo despeja nas colunas C e D para que você possa ver os dados originais. Altere [c1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y) para [a1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y) para despejar seus dados originais

[Atualizado com o regexp para remover todos os espaços em branco após , ie ", banda" se torna "banda"]

Sub SliceNDice() 
Dim objRegex As Object 
Dim X 
Dim Y 
Dim lngRow As Long 
Dim lngCnt As Long 
Dim tempArr() As String 
Dim strArr 
Set objRegex = CreateObject("vbscript.regexp") 
objRegex.Pattern = "^\s+(.+?)$" 
 'Define the range to be analysed
X = Range([a1], Cells(Rows.Count, "b").End(xlUp)).Value2 
Redim Y(1 To 2, 1 To 1000) 
For lngRow = 1 To UBound(X, 1) 
     'Split each string by ","
    tempArr = Split(X(lngRow, 2), ",") 
    For Each strArr In tempArr 
        lngCnt = lngCnt + 1 
         'Add another 1000 records to resorted array every 1000 records
        If lngCnt Mod 1000 = 0 Then Redim Preserve Y(1 To 2, 1 To lngCnt + 1000) 
        Y(1, lngCnt) = X(lngRow, 1) 
        Y(2, lngCnt) = objRegex.Replace(strArr, "$1") 
    Next 
Next lngRow 
 'Dump the re-ordered range to columns C:D
[c1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y) 
End Sub 

enter image description here

25
brettdj

Coloca seus dados na coluna A e coloca os resultados na coluna C.

Sub SplitAll()
    Dim src As Range
    Dim result As Variant
    For Each src In Range("A:A").SpecialCells(xlCellTypeConstants)
        result = Split(src, ",")
        'last cell in column C
        With Cells(Rows.Count, 3).End(xlUp)
            Range(.Offset(1, 0), .Offset(1 + UBound(result, 1), 0)) = Application.WorksheetFunction.Transpose(result)
        End With
    Next src
End Sub
5
Patrick Honorez